{
  description = "Root System NixOS flake";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.05";

    home-manager = {
      url = "github:nix-community/home-manager/release-25.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    lix-module = {
      url = "https://git.lix.systems/lix-project/nixos-module/archive/2.93.3-1.tar.gz";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    oscgoesbrrr = {
      url = "github:TheButlah/OscGoesBrrr";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nixgl = {
      url = "github:nix-community/nixGL";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # baballonia = {
    #   url = "github:Project-Babble/Baballonia";
    #   inputs.nixpkgs.follows = "nixpkgs";
    # };

    # lemonake.url = "github:passivelemon/lemonake";

    # wayvr-dashbourd.url = "github:PassiveLemon/lemonake/master/pkgs/wayvr-dashboard"
  };

  outputs = { self, nixpkgs, lix-module, home-manager,  ...}@inputs:
    {
      nixosConfigurations.pewter =
        let
          system = "x86_64-linux";
          xrizer = ({config, pkgs, lib, ... }:
            {
              nixpkgs.overlays = [
                (final: prev: {
                  xrizer =
                    let
                      src = final.fetchFromGitHub {
                        owner = "Mr-Zero88";
                        repo = "xrizer";
                        # IMPORTANT: Fill the below field with the latest commit hash from https://github.com/Mr-Zero88-FBT/xrizer/commits/experimental2 (click the Copy full SHA button on the right side)
                        rev = "63f6c00";
                        # IMPORTANT: Replace the below field with the correct hash, the error when building with this empty will give you the expected hash.
                        hash = "sha256-ilPNar7sfdQ5aSeypy5BStEGeVAoXtHw/iWLhqKEsPQ=";
                      };
                    in
                     prev.xrizer.overrideAttrs (drv: {
                      cargoDeps = drv.cargoDeps.overrideAttrs {
                        src = src;
                        outputHashMode = "recursive";
                        outputHash = "sha256-Z6zTjiuY4avAH/Bh9kofk+nbmHSSvCXaSCQp++w3cOE=";
                      };
                      patches = [];
                      # cargoSha256 = "";
                     });
                })
              ];
            });

          pkgs = import nixpkgs {
            system = system;
          };
        in
          nixpkgs.lib.nixosSystem {
            system = "x86_64-linux";
            specialArgs = inputs;
            modules = [
              lix-module.nixosModules.default
              ./configuration.nix
              xrizer
              home-manager.nixosModules.home-manager
              {
                home-manager.useGlobalPkgs = true;
                home-manager.useUserPackages = true;
                home-manager.users.abby = ./home.nix;

                home-manager.extraSpecialArgs = {
                  username = "abby";
                  inherit inputs;
                  system = system;
                };
              }
            ];
          };
      homeConfigurations."abby@copper" =
        let
          system = "aarch64-linux";
          pkgs = import nixpkgs {
            system = system;
            overlays = [ inputs.nixgl.overlay ];
          };
        in
          home-manager.lib.homeManagerConfiguration {
            inherit pkgs;
            modules = [
              lix-module.nixosModules.default
              ./home.nix
            ];
            extraSpecialArgs = {
              inherit system;
              username = "abby";
              inherit inputs;
            };
          };
      homeConfigurations."pager@nicrosil" =
        let
          system = "x86_64-linux";
          pkgs = import nixpkgs {
            system = system;
            overlays = [ inputs.nixgl.overlay ];
          };
        in
          home-manager.lib.homeManagerConfiguration {

            inherit pkgs;
            # specialArgs = inputs;
            modules = [
              lix-module.nixosModules.default
              ./home.nix
            ];
            extraSpecialArgs = {
              username = "pager";
              inherit inputs;
            };
          };
    };
}